1 files changed, 75 insertions, 0 deletions
diff --git a/pkgs/by-name/ca/cage/package.nix b/pkgs/by-name/ca/cage/package.nix
new file mode 100644
index 000000000000..d11cb43ba4fd
--- /dev/null
+++ b/pkgs/by-name/ca/cage/package.nix
@@ -0,0 +1,75 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  wayland-scanner,
+  scdoc,
+  makeWrapper,
+  wlroots_0_18,
+  wayland,
+  wayland-protocols,
+  pixman,
+  libxkbcommon,
+  xcbutilwm,
+  systemd,
+  libGL,
+  libX11,
+  xwayland ? null,
+  nixosTests,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cage";
+  version = "0.2.0";
+
+  src = fetchFromGitHub {
+    owner = "cage-kiosk";
+    repo = "cage";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-2SFtz62z0EF8cpFTC6wGi125MD4a5mkXqP/C+7fH+3g=";
+  };
+
+  depsBuildBuild = [
+    pkg-config
+  ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    wayland-scanner
+    scdoc
+    makeWrapper
+  ];
+
+  buildInputs = [
+    wlroots_0_18
+    wayland
+    wayland-protocols
+    pixman
+    libxkbcommon
+    xcbutilwm
+    systemd
+    libGL
+    libX11
+  ];
+
+  postFixup = lib.optionalString wlroots_0_18.enableXWayland ''
+    wrapProgram $out/bin/cage --prefix PATH : "${xwayland}/bin"
+  '';
+
+  # Tests Cage using the NixOS module by launching xterm:
+  passthru.tests.basic-nixos-module-functionality = nixosTests.cage;
+
+  meta = {
+    description = "Wayland kiosk that runs a single, maximized application";
+    homepage = "https://www.hjdskes.nl/projects/cage/";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ primeos ];
+    mainProgram = "cage";
+  };
+})