From 7f7924e0e4b6b07e8d9964b237a22ce12ff4b4ef Mon Sep 17 00:00:00 2001
From: Seth Flynn <getchoo@tuta.io>
Date: Wed, 2 Apr 2025 00:55:59 -0400
Subject: exercise-timer: init at 1.8.1

(cherry picked from commit cc940c97ea4d8997fac29affadeb12e223616fc4)
---
 pkgs/by-name/ex/exercise-timer/package.nix | 71 ++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 pkgs/by-name/ex/exercise-timer/package.nix

diff --git a/pkgs/by-name/ex/exercise-timer/package.nix b/pkgs/by-name/ex/exercise-timer/package.nix
new file mode 100644
index 000000000000..0f28d728448b
--- /dev/null
+++ b/pkgs/by-name/ex/exercise-timer/package.nix
@@ -0,0 +1,71 @@
+{
+  lib,
+  stdenv,
+  alsa-lib,
+  appstream-glib,
+  cargo,
+  desktop-file-utils,
+  fetchFromGitHub,
+  glib,
+  gtk4,
+  libadwaita,
+  meson,
+  ninja,
+  nix-update-script,
+  pkg-config,
+  rustPlatform,
+  rustc,
+  wrapGAppsHook4,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "exercise-timer";
+  version = "1.8.1";
+
+  src = fetchFromGitHub {
+    owner = "mfep";
+    repo = "exercise-timer";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-6MBSUYFZ8nMZX7acam8T0uJWb9E2/L9vnKzJq14p4BY=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-fmY89VGv9tSMaILFnAVTAyp9PWGsvSCZ/9DfF5LI3xM=";
+  };
+
+  nativeBuildInputs = [
+    appstream-glib
+    cargo
+    desktop-file-utils
+    glib
+    gtk4
+    meson
+    ninja
+    pkg-config
+    rustPlatform.cargoSetupHook
+    rustc
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    alsa-lib
+    libadwaita
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Timer app for high intensity interval training";
+    homepage = "https://apps.gnome.org/Hiit/";
+    changelog = "https://github.com/mfep/exercise-timer/blob/v${finalAttrs.version}/CHANGELOG.md";
+    license = lib.licenses.gpl3Only;
+    maintainers = lib.teams.gnome-circle.members;
+    mainProgram = "hiit";
+    platforms = lib.platforms.linux;
+  };
+})
-- 
cgit v1.2.3