blob: 3e4ee48340f40f8ed9f03c738919c61ca13fb2c3 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
{
lib,
buildGoModule,
fetchFromGitHub,
installShellFiles,
versionCheckHook,
}:
buildGoModule (finalAttrs: {
pname = "containerlab";
version = "0.69.1";
src = fetchFromGitHub {
owner = "srl-labs";
repo = "containerlab";
tag = "v${finalAttrs.version}";
hash = "sha256-+KZrKOxn9M+iKtugH89bPc106NGLwErMgIyiaU2kcGE=";
};
vendorHash = "sha256-YmE2eR5UnXy2nXTQP2FdyPQLAQVYPzDTmLrWtbRknAs=";
nativeBuildInputs = [
installShellFiles
versionCheckHook
];
ldflags = [
"-s"
"-w"
"-X github.com/srl-labs/containerlab/cmd/version.Version=${finalAttrs.version}"
"-X github.com/srl-labs/containerlab/cmd/version.commit=${finalAttrs.src.rev}"
"-X github.com/srl-labs/containerlab/cmd/version.date=1970-01-01T00:00:00Z"
];
preCheck = ''
# Fix failed TestLabelsInit test
export USER="runner"
'';
# TestVerifyLinks wants to use docker.sock, which is not available in the Nix build environment.
checkFlags = [
"-skip=^TestVerifyLinks$"
];
postInstall = ''
local INSTALL="$out/bin/containerlab"
installShellCompletion --cmd containerlab \
--bash <($out/bin/containerlab completion bash) \
--fish <($out/bin/containerlab completion fish) \
--zsh <($out/bin/containerlab completion zsh)
'';
doInstallCheck = true;
versionCheckProgramArg = "version";
meta = {
description = "Container-based networking lab";
homepage = "https://containerlab.dev/";
changelog = "https://github.com/srl-labs/containerlab/releases/tag/v${finalAttrs.version}";
license = lib.licenses.bsd3;
platforms = lib.platforms.linux;
maintainers = with lib.maintainers; [ aaronjheng ];
mainProgram = "containerlab";
};
})
|
