blob: fecffcda77fcfe4aa6b449ee47d41a8cb16308ea (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
{
lib,
buildGoModule,
fetchFromGitHub,
gitMinimal,
python3,
versionCheckHook,
nix-update-script,
}:
buildGoModule (finalAttrs: {
pname = "databricks-cli";
version = "0.263.0";
src = fetchFromGitHub {
owner = "databricks";
repo = "cli";
rev = "v${finalAttrs.version}";
hash = "sha256-bRHZGoO7+k7HoXcyJMusqDnn3XoAesgZ280j8jNgQYY=";
};
# Otherwise these tests fail asserting that the version is 0.0.0-dev
postPatch = ''
substituteInPlace bundle/deploy/terraform/init_test.go \
--replace-fail "cli/0.0.0-dev" "cli/${finalAttrs.version}"
'';
vendorHash = "sha256-sJyinqKX4irO4rquJ1hxDU/GH4XcyxPGw7qH0ZLgdxU=";
excludedPackages = [
"bundle/internal"
"acceptance"
"integration"
];
ldflags = [
"-X github.com/databricks/cli/internal/build.buildVersion=${finalAttrs.version}"
];
postBuild = ''
mv "$GOPATH/bin/cli" "$GOPATH/bin/databricks"
'';
checkFlags =
"-skip="
+ (lib.concatStringsSep "|" [
# Need network
"TestConsistentDatabricksSdkVersion"
"TestTerraformArchiveChecksums"
"TestExpandPipelineGlobPaths"
"TestRelativePathTranslationDefault"
"TestRelativePathTranslationOverride"
"TestWorkspaceVerifyProfileForHost"
"TestWorkspaceVerifyProfileForHost/default_config_file_with_match"
"TestWorkspaceResolveProfileFromHost"
"TestWorkspaceResolveProfileFromHost/no_config_file"
"TestBundleConfigureDefault"
# Use uv venv which doesn't work with nix
# https://github.com/astral-sh/uv/issues/4450
"TestVenvSuccess"
"TestPatchWheel"
]);
nativeCheckInputs = [
gitMinimal
(python3.withPackages (
ps: with ps; [
setuptools
wheel
]
))
];
preCheck = ''
# Some tested depends on git and remote url
git init
git remote add origin https://github.com/databricks/cli.git
'';
__darwinAllowLocalNetworking = true;
nativeInstallCheckInputs = [
versionCheckHook
];
versionCheckProgram = "${placeholder "out"}/bin/databricks";
versionCheckProgramArg = "--version";
doInstallCheck = true;
passthru = {
updateScript = nix-update-script { };
};
meta = {
description = "Databricks CLI";
mainProgram = "databricks";
homepage = "https://github.com/databricks/cli";
changelog = "https://github.com/databricks/cli/releases/tag/v${finalAttrs.version}";
license = lib.licenses.databricks;
maintainers = with lib.maintainers; [
kfollesdal
taranarmo
];
};
})
|
