blob: de9a4bcaecb719ab03c5b551fc1f05349bb01501 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
{
lib,
stdenv,
fetchFromGitHub,
pkg-config,
vst2-sdk,
wine64,
enableJackAssWine64 ? false,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "jackass";
version = "1.1";
src = fetchFromGitHub {
owner = "falkTX";
repo = "JackAss";
rev = "v${finalAttrs.version}";
hash = "sha256-6mqG4H6iGvDbGnmMeP/vcvSnvUGClZUl06XpKovt50E=";
};
postPatch = ''
cp -r ${vst2-sdk}/{public.sdk,pluginterfaces} vstsdk2.4
'';
nativeBuildInputs = [ pkg-config ] ++ lib.optionals enableJackAssWine64 [ wine64 ];
makeFlags = [ "linux" ] ++ lib.optionals enableJackAssWine64 [ "wine64" ];
installPhase = ''
runHook preInstall
install_dir="$out/lib/vst"
mkdir -p $install_dir
for file in JackAss.so JackAssWine64.dll; do
if test -f "$file"; then
cp $file $install_dir
fi
done
runHook postInstall
'';
enableParallelBuilding = true;
meta = {
description = "VST plugin that provides JACK-MIDI support for VST hosts";
longDescription = ''
Simply load the plugin in your favourite host to get a JACK-MIDI port.
Optionally includes a special Wine build for running in Wine
applications. Set enableJackAssWine64 to true to enable this output.
'';
homepage = "https://github.com/falkTX/JackAss";
maintainers = with lib.maintainers; [ PowerUser64 ];
license = [ lib.licenses.mit ];
platforms = lib.platforms.linux;
};
})
|
