1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# This script was inspired by the ArchLinux User Repository package:
#
# https://aur.archlinux.org/cgit/aur.git/tree/PKGBUILD?h=oh-my-zsh-git
{
lib,
stdenv,
fetchFromGitHub,
nixosTests,
writeScript,
common-updater-scripts,
git,
nix,
jq,
coreutils,
gnused,
curl,
cacert,
bash,
}:
stdenv.mkDerivation rec {
version = "2025-08-08";
pname = "oh-my-zsh";
src = fetchFromGitHub {
owner = "ohmyzsh";
repo = "ohmyzsh";
rev = "9d8d4cf41482a95127ca41faecc0a7ee0781ca2e";
sha256 = "sha256-u98vvBhGYfvfYmo/J8hBc6bDui5HVlgM3hY32LwJGio=";
};
strictDeps = true;
buildInputs = [ bash ];
installPhase = ''
runHook preInstall
outdir=$out/share/oh-my-zsh
template=templates/zshrc.zsh-template
mkdir -p $outdir
cp -r * $outdir
cd $outdir
rm LICENSE.txt
rm -rf .git*
chmod -R +w templates
# Change the path to oh-my-zsh dir and disable auto-updating.
sed -i -e "s#ZSH=\"\$HOME/.oh-my-zsh\"#ZSH=\"$outdir\"#" \
-e 's/\# \(DISABLE_AUTO_UPDATE="true"\)/\1/' \
$template
chmod +w oh-my-zsh.sh
# Both functions expect oh-my-zsh to be in ~/.oh-my-zsh and try to
# modify the directory.
cat >> oh-my-zsh.sh <<- EOF
# Undefine functions that don't work on Nix.
unfunction uninstall_oh_my_zsh
unfunction upgrade_oh_my_zsh
EOF
# Look for .zsh_variables, .zsh_aliases, and .zsh_funcs, and source
# them, if found.
cat >> $template <<- EOF
# Load the variables.
if [ -f ~/.zsh_variables ]; then
. ~/.zsh_variables
fi
# Load the functions.
if [ -f ~/.zsh_funcs ]; then
. ~/.zsh_funcs
fi
# Load the aliases.
if [ -f ~/.zsh_aliases ]; then
. ~/.zsh_aliases
fi
EOF
runHook postInstall
'';
passthru = {
tests = { inherit (nixosTests) oh-my-zsh; };
updateScript = writeScript "update.sh" ''
#!${stdenv.shell}
set -o errexit
PATH=${
lib.makeBinPath [
common-updater-scripts
curl
cacert
git
nix
jq
coreutils
gnused
]
}
oldVersion="$(nix-instantiate --eval -E "with import ./. {}; lib.getVersion oh-my-zsh" | tr -d '"')"
latestSha="$(curl -L -s https://api.github.com/repos/ohmyzsh/ohmyzsh/commits\?sha\=master\&since\=$oldVersion | jq -r '.[0].sha')"
if [ ! "null" = "$latestSha" ]; then
latestDate="$(curl -L -s https://api.github.com/repos/ohmyzsh/ohmyzsh/commits/$latestSha | jq '.commit.committer.date' | sed 's|"\(.*\)T.*|\1|g')"
update-source-version oh-my-zsh "$latestDate" --rev="$latestSha"
else
echo "${pname} is already up-to-date"
fi
'';
};
meta = with lib; {
description = "Framework for managing your zsh configuration";
longDescription = ''
Oh My Zsh is a framework for managing your zsh configuration.
To copy the Oh My Zsh configuration file to your home directory, run
the following command:
$ cp -v $(nix-env -q --out-path oh-my-zsh | cut -d' ' -f3)/share/oh-my-zsh/templates/zshrc.zsh-template ~/.zshrc
'';
homepage = "https://ohmyz.sh/";
license = licenses.mit;
platforms = platforms.all;
maintainers = with maintainers; [ nequissimus ];
};
}
|
