blob: b5e4223fa727348215a0f2f4925ddbf07a747dcb (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
{
lib,
stdenv,
overrideSDK,
cmakeMinimal,
fetchFromGitHub,
ninja,
testers,
aws-lc,
useSharedLibraries ? !stdenv.hostPlatform.isStatic,
}:
let
awsStdenv = if stdenv.hostPlatform.isDarwin then overrideSDK stdenv "11.0" else stdenv;
in
awsStdenv.mkDerivation (finalAttrs: {
pname = "aws-lc";
version = "1.49.1";
src = fetchFromGitHub {
owner = "aws";
repo = "aws-lc";
rev = "v${finalAttrs.version}";
hash = "sha256-gnYtzXHaS7QLcVmIcQsQDy6wNesQJ2ruE9W32HqiA5A=";
};
outputs = [
"out"
"bin"
"dev"
];
nativeBuildInputs = [
cmakeMinimal
ninja
];
cmakeFlags = [
(lib.cmakeBool "BUILD_SHARED_LIBS" useSharedLibraries)
"-GNinja"
"-DDISABLE_GO=ON"
"-DDISABLE_PERL=ON"
"-DBUILD_TESTING=ON"
];
doCheck = true;
checkPhase = ''
runHook preCheck
ninja run_minimal_tests
runHook postCheck
'';
env.NIX_CFLAGS_COMPILE = toString (
lib.optionals stdenv.cc.isGNU [
# Needed with GCC 12 but breaks on darwin (with clang)
"-Wno-error=stringop-overflow"
]
);
postFixup = ''
for f in $out/lib/crypto/cmake/*/crypto-targets.cmake; do
substituteInPlace "$f" \
--replace-fail 'INTERFACE_INCLUDE_DIRECTORIES "''${_IMPORT_PREFIX}/include"' 'INTERFACE_INCLUDE_DIRECTORIES ""'
done
'';
passthru.tests = {
version = testers.testVersion {
package = aws-lc;
command = "bssl version";
};
pkg-config = testers.hasPkgConfigModules {
package = aws-lc;
moduleNames = [
"libcrypto"
"libssl"
"openssl"
];
};
};
meta = {
description = "General-purpose cryptographic library maintained by the AWS Cryptography team for AWS and their customers";
homepage = "https://github.com/aws/aws-lc";
license = [
lib.licenses.asl20 # or
lib.licenses.isc
];
maintainers = [ lib.maintainers.theoparis ];
platforms = lib.platforms.unix;
mainProgram = "bssl";
};
})
|
