pkgs/by-name/el/elm-land/package.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

{
  lib,
  buildNpmPackage,
  fetchFromGitHub,
  elmPackages,
  versionCheckHook,
  writeShellScript,
  nix-update,
  elm2nix,
  nixfmt-rfc-style,
}:

buildNpmPackage rec {
  pname = "elm-land";
  version = "0.20.1";

  src = fetchFromGitHub {
    owner = "elm-land";
    repo = "elm-land";
    rev = "v${version}";
    hash = "sha256-PFyiVTH2Cek377YZwaCmvDToQCaxWQvJrQkRhyNI2Wg=";
  };

  sourceRoot = "${src.name}/projects/cli";

  npmDepsHash = "sha256-Bg16s0tqEaUT+BbFMKuEtx32rmbZLIILp8Ra/dQGmUg=";

  npmRebuildFlags = [ "--ignore-scripts" ];

  postConfigure =
    (elmPackages.fetchElmDeps {
      elmPackages = import ./elm-srcs.nix;
      elmVersion = elmPackages.elm.version;
      registryDat = ./registry.dat;
    })
    + ''
      ln -sf ${lib.getExe elmPackages.elm} node_modules/.bin/elm
    '';

  nativeInstallCheckInputs = [
    versionCheckHook
  ];
  versionCheckProgramArg = "--version";
  doInstallCheck = true;

  passthru.updateScript = writeShellScript "update-elm-land" ''
    set -eu -o pipefail

    # Update version, src and npm deps
    ${lib.getExe nix-update} "$UPDATE_NIX_ATTR_PATH"

    # Update elm deps
    cp "$(nix-build -A "$UPDATE_NIX_ATTR_PATH".src)/projects/cli/src/codegen/elm.json" elm.json
    trap 'rm -rf elm.json registry.dat &> /dev/null' EXIT
    ${lib.getExe elm2nix} convert > pkgs/by-name/el/elm-land/elm-srcs.nix
    ${lib.getExe nixfmt-rfc-style} pkgs/by-name/el/elm-land/elm-srcs.nix
    ${lib.getExe elm2nix} snapshot
    cp registry.dat pkgs/by-name/el/elm-land/registry.dat
  '';

  meta = {
    description = "A production-ready framework for building Elm applications";
    homepage = "https://github.com/elm-land/elm-land";
    license = lib.licenses.bsd3;
    maintainers = with lib.maintainers; [
      domenkozar
      zupo
    ];
    mainProgram = "elm-land";
  };
}