1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
{
lib,
buildGoModule,
fetchFromGitHub,
# required for completion and cross-compilation
installShellFiles,
buildPackages,
stdenv,
# required for testing
testers,
fulcio,
}:
buildGoModule rec {
pname = "fulcio";
version = "1.6.6";
src = fetchFromGitHub {
owner = "sigstore";
repo = pname;
rev = "v${version}";
hash = "sha256-CfkHGHxeDUxHWX98FgmA4RNCVlgi9XA9eYkb+G5cZTA=";
# populate values that require us to use git. By doing this in postFetch we
# can delete .git afterwards and maintain better reproducibility of the src.
leaveDotGit = true;
postFetch = ''
cd "$out"
git rev-parse HEAD > $out/COMMIT
# 0000-00-00T00:00:00Z
date -u -d "@$(git log -1 --pretty=%ct)" "+%Y-%m-%dT%H:%M:%SZ" > $out/SOURCE_DATE_EPOCH
find "$out" -name .git -print0 | xargs -0 rm -rf
'';
};
vendorHash = "sha256-qQsaX/xaqD1qb9wH6riohm+NU49cN3EkO012oz9n4tw=";
nativeBuildInputs = [ installShellFiles ];
subPackages = [ "." ];
ldflags = [
"-s"
"-w"
"-X sigs.k8s.io/release-utils/version.gitVersion=v${version}"
"-X sigs.k8s.io/release-utils/version.gitTreeState=clean"
];
# ldflags based on metadata from git and source
preBuild = ''
ldflags+=" -X sigs.k8s.io/release-utils/version.gitCommit=$(cat COMMIT)"
ldflags+=" -X sigs.k8s.io/release-utils/version.buildDate=$(cat SOURCE_DATE_EPOCH)"
'';
preCheck = ''
# test all paths
unset subPackages
'';
checkFlags = [
"-skip=TestLoad"
];
postInstall =
let
fulcio =
if stdenv.buildPlatform.canExecute stdenv.hostPlatform then
placeholder "out"
else
buildPackages.fulcio;
in
''
installShellCompletion --cmd fulcio \
--bash <(${fulcio}/bin/fulcio completion bash) \
--fish <(${fulcio}/bin/fulcio completion fish) \
--zsh <(${fulcio}/bin/fulcio completion zsh)
'';
passthru.tests.version = testers.testVersion {
package = fulcio;
command = "fulcio version";
version = "v${version}";
};
meta = with lib; {
homepage = "https://github.com/sigstore/fulcio";
changelog = "https://github.com/sigstore/fulcio/releases/tag/v${version}";
description = "Root-CA for code signing certs - issuing certificates based on an OIDC email address";
mainProgram = "fulcio";
longDescription = ''
Fulcio is a free code signing Certificate Authority, built to make
short-lived certificates available to anyone. Based on an Open ID Connect
email address, Fulcio signs x509 certificates valid for under 20 minutes.
Fulcio was designed to run as a centralized, public-good instance backed
up by other transparency logs. Development is now underway to support
different delegation models, and to deploy and run Fulcio as a
disconnected instance.
'';
license = licenses.asl20;
maintainers = with maintainers; [
lesuisse
jk
];
};
}
|
