blob: c7cb86f6d6ef03edb3e22f23b7850118e910bb15 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
{
lib,
stdenv,
fetchurl,
which,
pkg-config,
gtk2,
pcre,
glib,
libxml2,
libsoup_2_4 ? null,
}:
stdenv.mkDerivation rec {
pname = "hardinfo";
version = "0.5.1";
src = fetchurl {
url = "mirror://sourceforge/project/hardinfo.berlios/hardinfo-${version}.tar.bz2";
sha256 = "0yhvfc5icam3i4mphlz0m9d9d2irjw8mbsxq203x59wjgh6nrpx0";
};
# Not adding 'hostname' command, the build shouldn't depend on what the build
# host is called.
nativeBuildInputs = [ pkg-config ];
buildInputs = [
which
gtk2
pcre
glib
libxml2
libsoup_2_4
];
# Fixes '#error You must compile this program without "-O"'
hardeningDisable = [ "all" ];
# Ignore undefined references to a bunch of libsoup symbols
NIX_LDFLAGS = "--unresolved-symbol=ignore-all";
preConfigure = ''
patchShebangs configure
# -std=gnu89 fixes build error, copied from
# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=757525
sed -i -e "s/^CFLAGS = \(.*\)/CFLAGS = \1 -std=gnu89/" Makefile.in
substituteInPlace ./arch/linux/common/modules.h --replace /sbin/modinfo modinfo
substituteInPlace ./arch/linux/common/os.h --replace /lib/libc.so.6 ${stdenv.cc.libc}/lib/libc.so
'';
# Makefile supports DESTDIR but not PREFIX (it hardcodes $DESTDIR/usr/).
installFlags = [ "DESTDIR=$(out)" ];
postInstall = ''
mv "$out/usr/"* "$out"
rmdir "$out/usr"
'';
meta = with lib; {
homepage = "http://hardinfo.org/";
description = "Display information about your hardware and operating system";
license = licenses.gpl2Only;
maintainers = with maintainers; [ bjornfor ];
platforms = [
"x86_64-linux"
"i686-linux"
]; # ARMv7 and AArch64 are unsupported
mainProgram = "hardinfo";
};
}
|
