blob: 4864cd0322f84bae2053ec09ffb8c34a5c432fed (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
{
stdenv,
lib,
buildGoModule,
fetchFromGitHub,
installShellFiles,
buildPackages,
versionCheckHook,
nix-update-script,
}:
buildGoModule rec {
pname = "hugo";
version = "0.145.0";
src = fetchFromGitHub {
owner = "gohugoio";
repo = "hugo";
tag = "v${version}";
hash = "sha256-5SV6VzNWGnFQBD0fBugS5kKXECvV1ZE7sk7SwJCMbqY=";
};
vendorHash = "sha256-aynhBko6ecYyyMG9XO5315kLerWDFZ6V8LQ/WIkvC70=";
checkFlags =
let
skippedTestPrefixes = [
# Workaround for "failed to load modules"
"TestCommands/mod"
# Server tests are flaky, at least in x86_64-darwin. See #368072
# We can try testing again after updating the `httpget` helper
# ref: https://github.com/gohugoio/hugo/blob/v0.140.1/main_test.go#L220-L233
"TestCommands/server"
];
in
[ "-skip=^${builtins.concatStringsSep "|^" skippedTestPrefixes}" ];
proxyVendor = true;
tags = [
"extended"
"withdeploy"
];
subPackages = [ "." ];
nativeBuildInputs = [ installShellFiles ];
ldflags = [
"-s"
"-w"
"-X github.com/gohugoio/hugo/common/hugo.vendorInfo=nixpkgs"
];
postInstall =
let
emulator = stdenv.hostPlatform.emulator buildPackages;
in
''
${emulator} $out/bin/hugo gen man
installManPage man/*
installShellCompletion --cmd hugo \
--bash <(${emulator} $out/bin/hugo completion bash) \
--fish <(${emulator} $out/bin/hugo completion fish) \
--zsh <(${emulator} $out/bin/hugo completion zsh)
'';
nativeInstallCheckInputs = [
versionCheckHook
];
doInstallCheck = true;
versionCheckProgram = "${placeholder "out"}/bin/${meta.mainProgram}";
versionCheckProgramArg = [ "version" ];
passthru.updateScript = nix-update-script { };
meta = {
changelog = "https://github.com/gohugoio/hugo/releases/tag/v${version}";
description = "Fast and modern static website engine";
homepage = "https://gohugo.io";
license = lib.licenses.asl20;
mainProgram = "hugo";
maintainers = with lib.maintainers; [
schneefux
Br1ght0ne
Frostman
kachick
federicoschonborn
];
};
}
|
