blob: 8c9db044107b5108d6ab820d7479315162300cd1 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
{
lib,
fetchFromGitHub,
buildNpmPackage,
electron_34,
makeWrapper,
testers,
mattermost-desktop,
nix-update-script,
}:
let
electron = electron_34;
in
buildNpmPackage rec {
pname = "mattermost-desktop";
version = "5.11.2";
src = fetchFromGitHub {
owner = "mattermost";
repo = "desktop";
tag = "v${version}";
hash = "sha256-03874pV7/GqydMdaSlh3N17LsbHppfPdYJ8nGdbvvbk=";
};
npmDepsHash = "sha256-v6XEJJ9kozkY7HSLNJtM+86+36G7wt8xIFwCyO7x11Y=";
npmBuildScript = "build-prod";
makeCacheWritable = true;
nativeBuildInputs = [ makeWrapper ];
env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
postPatch = ''
substituteInPlace webpack.config.base.js \
--replace-fail \
"const VERSION = childProcess.execSync('git rev-parse --short HEAD', {cwd: __dirname}).toString();" \
"const VERSION = process.env.version;"
'';
postBuild = ''
# electronDist needs to be writable
cp -r ${electron.dist} electron-dist
chmod -R u+w electron-dist
npm exec electron-builder -- \
--config electron-builder.json \
--dir \
-c.electronDist=electron-dist \
-c.electronVersion=${electron.version}
'';
installPhase = ''
runHook preInstall
mkdir --parents \
$out/bin \
$out/share/applications \
$out/share/icons/hicolor/512x512/apps
readonly dist=release/linux-unpacked
cp -a $dist/resources $out/share/${pname}
patchShebangs $dist/create_desktop_file.sh
$dist/create_desktop_file.sh
mv Mattermost.desktop $out/share/applications/
substituteInPlace $out/share/applications/Mattermost.desktop \
--replace-fail /build/source/$dist/app_icon.png ${pname} \
--replace-fail /build/source/$dist/ $out/bin/
cp src/assets/linux/app_icon.png $out/share/icons/hicolor/512x512/apps/${pname}.png
makeWrapper '${lib.getExe electron}' $out/bin/${pname} \
--set-default ELECTRON_IS_DEV 0 \
--add-flags $out/share/${pname}/app.asar \
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}"
runHook postInstall
'';
passthru = {
tests.version = testers.testVersion {
package = mattermost-desktop;
# Invoking with `--version` insists on being able to write to a log file.
command = "env HOME=/tmp ${meta.mainProgram} --version";
};
updateScript = nix-update-script {
extraArgs = [ "--version-regex=^(\\d+\\.\\d+\\.\\d+)$" ];
};
};
meta = {
description = "Mattermost Desktop client";
mainProgram = "mattermost-desktop";
homepage = "https://about.mattermost.com/";
changelog = "https://github.com/mattermost/desktop/releases/tag/${src.tag}";
license = lib.licenses.asl20;
platforms = electron.meta.platforms;
maintainers = with lib.maintainers; [
joko
liff
];
};
}
|
