blob: 21643bc581b2440f548ac67091012d487f02279f (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{
lib,
stdenv,
fetchFromGitHub,
cmake,
gtest,
pkg-config,
zlib,
bzip2,
xz,
zstd,
openssl,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "minizip-ng";
version = "4.0.9";
src = fetchFromGitHub {
owner = "zlib-ng";
repo = "minizip-ng";
rev = finalAttrs.version;
hash = "sha256-iAiw+ihVfcSNl6UdBad7FjT5Zwa+brndg60v7ceCzC8=";
};
nativeBuildInputs = [
cmake
pkg-config
];
buildInputs = [
zlib
bzip2
xz
zstd
openssl
];
cmakeFlags =
[
"-DBUILD_SHARED_LIBS=${if stdenv.hostPlatform.isStatic then "OFF" else "ON"}"
"-DMZ_OPENSSL=ON"
"-DMZ_BUILD_TESTS=${if finalAttrs.finalPackage.doCheck then "ON" else "OFF"}"
"-DMZ_BUILD_UNIT_TESTS=${if finalAttrs.finalPackage.doCheck then "ON" else "OFF"}"
"-DMZ_LIB_SUFFIX='-ng'"
]
++ lib.optionals stdenv.hostPlatform.isDarwin [
# missing header file
"-DMZ_LIBCOMP=OFF"
];
NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isDarwin "-Wno-register";
postInstall = ''
# make lib findable as libminizip-ng even if compat is enabled
for ext in so dylib a ; do
if [ -e $out/lib/libminizip.$ext ] && [ ! -e $out/lib/libminizip-ng.$ext ]; then
ln -s $out/lib/libminizip.$ext $out/lib/libminizip-ng.$ext
fi
done
if [ ! -e $out/include/minizip-ng ]; then
ln -s $out/include $out/include/minizip-ng
fi
'';
doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
nativeCheckInputs = [ gtest ];
enableParallelChecking = false;
meta = with lib; {
description = "Fork of the popular zip manipulation library found in the zlib distribution";
homepage = "https://github.com/zlib-ng/minizip-ng";
license = licenses.zlib;
maintainers = with maintainers; [
ris
];
platforms = platforms.unix;
};
})
|
