1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
{
stdenv,
lib,
fetchFromGitHub,
gitUpdater,
nixosTests,
boost,
cmake,
coreutils,
dbus,
glib,
glm,
gtest,
json_c,
libevdev,
libglvnd,
libnotify,
libuuid,
libxkbcommon,
libgbm,
makeWrapper,
mir,
nlohmann_json,
pcre2,
pkg-config,
systemd,
wayland,
yaml-cpp,
}:
stdenv.mkDerivation (finalAttrs: {
pname = "miracle-wm";
version = "0.5.2";
src = fetchFromGitHub {
owner = "miracle-wm-org";
repo = "miracle-wm";
tag = "v${finalAttrs.version}";
hash = "sha256-nmDFmj3DawgjRB0+vlcvPX+kj6lzAu14HySFc2NsJss=";
};
postPatch =
''
substituteInPlace CMakeLists.txt \
--replace-fail 'DESTINATION /usr/lib' 'DESTINATION ''${CMAKE_INSTALL_LIBDIR}' \
--replace-fail '-march=native' '# -march=native' \
--replace-fail '-flto' '# -flto'
''
+ lib.optionalString (!finalAttrs.finalPackage.doCheck) ''
substituteInPlace CMakeLists.txt \
--replace-fail 'add_subdirectory(tests/)' ""
'';
strictDeps = true;
# Source has a path "session/usr/local/...", don't break references to that
dontFixCmake = true;
nativeBuildInputs = [
cmake
makeWrapper
pkg-config
];
buildInputs = [
boost
glib
glm
json_c
libevdev
libglvnd
libnotify
libuuid
libxkbcommon
libgbm
mir
nlohmann_json
pcre2
wayland
yaml-cpp
];
checkInputs = [ gtest ];
cmakeFlags = [
(lib.cmakeBool "SYSTEMD_INTEGRATION" true)
];
doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
checkPhase = ''
runHook preCheck
./bin/miracle-wm-tests
runHook postCheck
'';
postFixup = ''
patchShebangs $out/libexec/miracle-wm-session-setup
wrapProgram $out/libexec/miracle-wm-session-setup \
--prefix PATH : "$out/bin:${
lib.makeBinPath [
coreutils # cat
dbus # dbus-update-activation-environment
systemd # systemctl
]
}"
'';
passthru = {
updateScript = gitUpdater { rev-prefix = "v"; };
providedSessions = [ "miracle-wm" ];
tests.vm = nixosTests.miracle-wm;
};
meta = {
description = "Tiling Wayland compositor based on Mir";
longDescription = ''
miracle-wm is a Wayland compositor based on Mir. It features a tiling window manager at its core, very much in
the style of i3 and sway. The intention is to build a compositor that is flashier and more feature-rich than
either of those compositors, like swayfx.
See the user guide for info on how to use miracle-wm: https://wiki.miracle-wm.org/v${finalAttrs.version}/
'';
homepage = "https://github.com/mattkae/miracle-wm";
changelog = "https://github.com/miracle-wm-org/miracle-wm/releases/tag/v${finalAttrs.version}";
license = lib.licenses.gpl3Only;
mainProgram = "miracle-wm";
maintainers = with lib.maintainers; [ OPNA2608 ];
platforms = lib.platforms.linux;
};
})
|
