blob: 8fe71fa96d2dde16017fd07fab4813dacdb1bf9d (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
{
buildGoModule,
fetchFromGitHub,
go,
lib,
makeWrapper,
}:
buildGoModule rec {
pname = "revive";
version = "1.9.0";
src = fetchFromGitHub {
owner = "mgechev";
repo = pname;
rev = "v${version}";
hash = "sha256-mHyXymMJZeHXYOB6JB5VTqeP1flOACnNE/dLApAenH4=";
# populate values that require us to use git. By doing this in postFetch we
# can delete .git afterwards and maintain better reproducibility of the src.
leaveDotGit = true;
postFetch = ''
date -u -d "@$(git -C $out log -1 --pretty=%ct)" "+%Y-%m-%d %H:%M UTC" > $out/DATE
git -C $out rev-parse HEAD > $out/COMMIT
rm -rf $out/.git
'';
};
vendorHash = "sha256-oRhex0WC0MUxX1luKJeMvA7NpN7aS/9ecXkrfRYEnvM=";
ldflags = [
"-s"
"-w"
"-X github.com/mgechev/revive/cli.version=${version}"
"-X github.com/mgechev/revive/cli.builtBy=nix"
];
# ldflags based on metadata from git and source
preBuild = ''
ldflags+=" -X github.com/mgechev/revive/cli.commit=$(cat COMMIT)"
ldflags+=" -X 'github.com/mgechev/revive/cli.date=$(cat DATE)'"
'';
allowGoReference = true;
nativeBuildInputs = [ makeWrapper ];
postFixup = ''
wrapProgram $out/bin/revive \
--prefix PATH : ${lib.makeBinPath [ go ]}
'';
meta = with lib; {
description = "Fast, configurable, extensible, flexible, and beautiful linter for Go";
mainProgram = "revive";
homepage = "https://revive.run";
license = licenses.mit;
maintainers = with maintainers; [ maaslalani ];
};
}
|
