blob: 0f7d07d0893be5362116dd392f091e882bf89cc2 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
{
stdenvNoCC,
lib,
fetchurl,
fetchzip,
appimageTools,
makeWrapper,
electron,
}:
(stdenvNoCC.mkDerivation rec {
pname = "revolt-desktop";
version = "1.0.8";
dontConfigure = true;
dontBuild = true;
meta = {
description = "Open source user-first chat platform";
homepage = "https://revolt.chat/";
changelog = "https://github.com/revoltchat/desktop/releases/tag/v${version}";
license = lib.licenses.agpl3Only;
maintainers = with lib.maintainers; [
heyimnova
caralice
];
platforms = lib.platforms.linux ++ lib.platforms.darwin;
sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
mainProgram = "revolt-desktop";
};
nativeBuildInputs = [ makeWrapper ];
}).overrideAttrs
(
final: prev:
let
inherit (prev) version;
in
if stdenvNoCC.hostPlatform.isLinux then
{
src =
{
x86_64-linux = fetchurl {
url = "https://github.com/revoltchat/desktop/releases/download/v${version}/Revolt-${version}.AppImage";
hash = "sha256-L23Je5p7VmQpOLC+IfmQRk2CKKUm4rNBdsYLvqLTlRY=";
};
armv7l-linux = fetchurl {
url = "https://github.com/revoltchat/desktop/releases/download/v${version}/Revolt-${version}-armv7l.AppImage";
hash = "sha256-Qwya5tgHjMB8IJi0ueGmkzgQMQu+rlsDoWIVpl6Vj2w=";
};
aarch64-linux = fetchurl {
url = "https://github.com/revoltchat/desktop/releases/download/v${version}/Revolt-${version}-arm64.AppImage";
hash = "sha256-VQXyXaL4Ma3peO1duAlyFwkb1CRQ/4DNZhjiAnhms6I=";
};
}
.${stdenvNoCC.hostPlatform.system}
or (throw "Unsupported system: ${stdenvNoCC.hostPlatform.system}");
appimageContents = appimageTools.extractType2 { inherit (final) src pname version; };
dontUnpack = true;
installPhase = ''
runHook preInstall
mkdir -p $out/bin $out/share/{applications,revolt-desktop}
cp -a ${final.appimageContents}/{locales,resources} $out/share/revolt-desktop
cp -a ${final.appimageContents}/revolt-desktop.desktop $out/share/applications/revolt-desktop.desktop
cp -a ${final.appimageContents}/usr/share/icons $out/share/icons
substituteInPlace $out/share/applications/revolt-desktop.desktop \
--replace-fail 'Exec=AppRun' 'Exec=revolt-desktop'
runHook postInstall
'';
postFixup = ''
makeWrapper ${electron}/bin/electron $out/bin/revolt-desktop \
--add-flags $out/share/revolt-desktop/resources/app.asar \
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform=wayland --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}"
'';
}
else
assert stdenvNoCC.hostPlatform.isDarwin;
{
src = fetchzip {
url = "https://github.com/revoltchat/desktop/releases/download/v${version}/Revolt-${version}-universal-mac.zip";
hash = "sha256-CpG1LLYYHa9ho4rotDwSS+wNIJ2z0kBPqu70xKEFg+k=";
stripRoot = false;
};
installPhase = ''
runHook preInstall
mkdir -p "$out/Applications/" "$out/bin/"
mv Revolt.app "$out/Applications/"
makeWrapper "$out/Applications/Revolt.app/Contents/MacOS/Revolt" "$out/bin/revolt-desktop"
runHook postInstall
'';
}
)
|
