blob: 17f70e0ac69228f010c64b9b0d8617aa7989a831 (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
{
stdenv,
lib,
fetchFromGitHub,
unstableGitUpdater,
makeWrapper,
glew,
SDL2,
writeShellScript,
}:
let
datadir = "\"\${XDG_DATA_HOME:-$HOME/.local/share}\"/wipeout-rewrite";
datadirCheck = writeShellScript "wipeout-rewrite-check-datadir.sh" ''
datadir=${datadir}
if [ ! -d "$datadir" ]; then
echo "[Wrapper] Creating data directory $datadir"
mkdir -p "$datadir"
fi
echo "[Wrapper] Remember to put your game assets into $datadir/wipeout if you haven't done so yet!"
echo "[Wrapper] Check https://github.com/phoboslab/wipeout-rewrite#running for the required format."
'';
in
stdenv.mkDerivation (finalAttrs: {
pname = "wipeout-rewrite";
version = "0-unstable-2024-11-09";
src = fetchFromGitHub {
owner = "phoboslab";
repo = "wipeout-rewrite";
rev = "05e9c2d3a1272e631e256a76b89aca235b92e4a9";
hash = "sha256-rzwh4JZNea5Wu/BEWGWpfxyPjY0GLrUPynPTbUC9Mak=";
};
enableParallelBuilding = true;
nativeBuildInputs = [
makeWrapper
];
buildInputs = [
glew
SDL2
];
# Force this to empty, so assets are looked up in CWD instead of $out/bin
env.NIX_CFLAGS_COMPILE = "-DPATH_ASSETS=";
installPhase = ''
runHook preInstall
install -Dm755 wipegame $out/bin/wipegame
# I can't get --chdir to not expand the bash variables in datadir at build time (so they point to /homeless-shelter)
# or put them inside single quotes (breaking the expansion at runtime)
wrapProgram $out/bin/wipegame \
--run '${datadirCheck}' \
--run 'cd ${datadir}'
runHook postInstall
'';
passthru.updateScript = unstableGitUpdater { };
meta = {
mainProgram = "wipegame";
description = "Re-implementation of the 1995 PSX game wipEout";
homepage = "https://github.com/phoboslab/wipeout-rewrite";
license = lib.licenses.unfree;
maintainers = with lib.maintainers; [ OPNA2608 ];
platforms = lib.platforms.all;
};
})
|
