blob: 552e70a547b5503f9e5724f4c57000a07edf1f1d (
about) (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
{
lib,
stdenv,
fetchFromGitLab,
buildLinux,
variant,
...
}@args:
let
# These names are how they are designated in https://xanmod.org.
# NOTE: When updating these, please also take a look at the changes done to
# kernel config in the xanmod version commit
variants = {
lts = {
version = "6.12.21";
hash = "sha256-Zb/n+hLho94+6u5BHAmRYfit/kv1xlh/Tp39kI3kfjA=";
};
main = {
version = "6.13.9";
hash = "sha256-JRmyvlvU8NOQ4aLdZ2BmQWUnl1RGjcjucaWN4zVxQpg=";
};
};
xanmodKernelFor =
{
version,
suffix ? "xanmod1",
hash,
}:
buildLinux (
args
// rec {
inherit version;
pname = "linux-xanmod";
modDirVersion = lib.versions.pad 3 "${version}-${suffix}";
src = fetchFromGitLab {
owner = "xanmod";
repo = "linux";
rev = modDirVersion;
inherit hash;
};
structuredExtraConfig = with lib.kernel; {
# CPUFreq governor Performance
CPU_FREQ_DEFAULT_GOV_PERFORMANCE = lib.mkOverride 60 yes;
CPU_FREQ_DEFAULT_GOV_SCHEDUTIL = lib.mkOverride 60 no;
# Full preemption
PREEMPT = lib.mkOverride 60 yes;
PREEMPT_VOLUNTARY = lib.mkOverride 60 no;
# Google's BBRv3 TCP congestion Control
TCP_CONG_BBR = yes;
DEFAULT_BBR = yes;
# Preemptive Full Tickless Kernel at 250Hz
HZ = freeform "250";
HZ_250 = yes;
HZ_1000 = no;
# RCU_BOOST and RCU_EXP_KTHREAD
RCU_EXPERT = yes;
RCU_FANOUT = freeform "64";
RCU_FANOUT_LEAF = freeform "16";
RCU_BOOST = yes;
RCU_BOOST_DELAY = freeform "0";
RCU_EXP_KTHREAD = yes;
};
extraMeta = {
branch = lib.versions.majorMinor version;
maintainers = with lib.maintainers; [
moni
lovesegfault
atemu
zzzsy
eljamm
];
description = "Built with custom settings and new features built to provide a stable, responsive and smooth desktop experience";
broken = stdenv.hostPlatform.isAarch64;
};
}
// (args.argsOverride or { })
);
in
xanmodKernelFor variants.${variant}
|
