1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
{
lib,
stdenv,
fetchurl,
pkg-config,
libcap_ng,
libnl,
lz4,
lzo,
openssl,
pam,
useSystemd ? lib.meta.availableOn stdenv.hostPlatform systemd,
systemd,
update-systemd-resolved,
pkcs11Support ? false,
pkcs11helper,
nixosTests,
unixtools,
}:
let
inherit (lib) optional optionals optionalString;
in
stdenv.mkDerivation (finalAttrs: {
pname = "openvpn";
version = "2.6.13";
src = fetchurl {
url = "https://swupdate.openvpn.net/community/releases/openvpn-${finalAttrs.version}.tar.gz";
hash = "sha256-GvELhpIr18mYJ8wPFR3+loQze45evbOXU5FyhBrCSmo=";
};
nativeBuildInputs =
[ pkg-config ]
++ lib.optionals stdenv.hostPlatform.isDarwin [
unixtools.route
unixtools.ifconfig
];
buildInputs =
[
lz4
lzo
openssl
]
++ optionals stdenv.hostPlatform.isLinux [
libcap_ng
libnl
pam
]
++ optional useSystemd systemd
++ optional pkcs11Support pkcs11helper;
configureFlags =
optional useSystemd "--enable-systemd"
++ optional pkcs11Support "--enable-pkcs11"
++ optional stdenv.hostPlatform.isDarwin "--disable-plugin-auth-pam";
# We used to vendor the update-systemd-resolved script inside libexec,
# but a separate package was made, that uses libexec/openvpn. Copy it
# into libexec in case any consumers expect it to be there even though
# they should use the update-systemd-resolved package instead.
postInstall =
''
mkdir -p $out/share/doc/openvpn/examples
cp -r sample/sample-{config-files,keys,scripts}/ $out/share/doc/openvpn/examples
''
+ optionalString useSystemd ''
install -Dm555 -t $out/libexec ${update-systemd-resolved}/libexec/openvpn/*
'';
enableParallelBuilding = true;
passthru.tests = {
inherit (nixosTests) initrd-network-openvpn systemd-initrd-networkd-openvpn;
};
meta = with lib; {
description = "Robust and highly flexible tunneling application";
downloadPage = "https://openvpn.net/community-downloads/";
homepage = "https://openvpn.net/";
license = licenses.gpl2Only;
maintainers = with maintainers; [ peterhoeg ];
platforms = platforms.unix;
mainProgram = "openvpn";
};
})
|
